10　SCREEN1,1,1:CONSOLE0,16,0
20　CLS:FORI=1TO7:READA$(I):NEXT
30　FORC=0TO7:FORI=1TO4:READB$(C,I):NEXTI,C
40　PRINTSPC(8)"＞＞＞　ＴＨＥ　ＳＰＹ　＜＜＜
50　PRINT:PRINT"　きみはスハ゜イた゛。てきこくたいしかんからひみつしょるいをぬすみた゛すのか゛、こんかいのに";
60　PRINT"んむた゛。つこ゛うのよいことに、きょうはたいしかんか゛るすらしい。そのあいた゛に、ひみつしょるいをぬすみ";
70　PRINT"た゛してほしい。せいこうをいのる。
80　PRINT:PRINT"・たいしかんはろうかと８つのへやからて゛きていて、いと゛うはカー　ソルキーて゛おこなう。
90　PRINT"・へやにはいるとコマント゛か゛ひょうし゛されるのて゛、たいおうす　るキーをおす。
100　PRINT"・コマント゛をキャンセルするときは、０キーをおす。
110　PRINT"・へやをて゛ると、そのへやはもとのし゛ょうたいにもと゛る。
120　PRINT:PRINTSPC(9)"ＨＩＴ　ＳＰＡＣＥ　ＫＥＹ
130　IFSTRIG(0)=0THEN130
140　CLS:PRINT"１Ｆ　ＵＰ　　２Ｆ　ＤＯＷＮ
150　PRINT"┏━┳┻┳━┓┏━┳┻┳━┓
160　PRINT"┃　Ｉ　Ｉ　┃┃　Ｉ　Ｉ　┃
170　PRINT"┣━┫　┣━┫┣━┫　┣━┫
180　PRINT"┃　Ｉ　Ｉ　┃┃　Ｉ　Ｉ　┃
190　PRINT"┗━┻━┻━┛┗━┻━┻━┛
200　LOCATE24,6:PRINT"┏もちもの━┓
210　FORI=1TO6:PRINTSPC(24)"┃　　　　　┃":NEXT
220　PRINTSPC(24)"┗━━━━━┛
230　F=3-(B>1)*7:G=2-(B=0ORB=3)*2
240　LOCATEF,G:PRINT"○
250　I=STICK(0):IFI+1AND1THEN250
260　IFI=1THENB=B-(B<2)+(B>1)
270　IFI=5THENB=B-(B=2)+(B=1)
280　LOCATEF,G:PRINT"　"
290　IF(IAND3)<3THEN230
300　C=B+B-(I=3)
310　D=0:F=F-(I=3)*2+(I=7)*2:LOCATEF,G:PRINT"○
320　LOCATE15,0:PRINT"このへやにあるもの
330　J=3:FORI=1TO3:LOCATE16,I
340　PRINTB$(C,I):NEXT
350　LOCATE16,4:PRINT"　　　　　　"
360　FORI=1TO7:LOCATE0,6+I:PRINTI"　"A$(I):NEXT
370　FORI=7TO11:LOCATE11,I:PRINTSPC(8):NEXT
380　H=7:GOSUB1560
390　IFC=8ANDI<6THENA$="まっくらて゛なにもみえません。":GOTO420
400　IFI=7THEN430
410　ONIGOSUB450,670,720,780,1090,1190:IFI=0THEN360
420　LOCATE0,15:PRINTSPC(29);:LOCATE0,15:PRINTA$;:GOTO360
430　I=0:FORI=0TO4:LOCATE15,I:PRINTSPC(9):NEXT:LOCATE0,15
440　PRINTSPC(29):FORI=7TO13:LOCATE0,I:PRINTSPC(19):NEXT:GOTO280
450　GOSUB760:IFI=0THENRETURN
460　IFC+(EAND8)=0ANDI*(DAND1)=2THENA$="ライト":I=8:GOTO1490
470　IFI-C=4AND(DAND4)+(EAND1)=4THENA$="かき゛":I=1:GOTO1490
480　IFC=1ANDI+(EAND16)=3THENA$="ハンマー":I=16:GOTO1490
490　IFC=2ANDI=4AND(DAND4)+(EAND2)=4THENA$="かき゛":I=2:GOTO1490
500　IFC*I=16AND(DAND4)+(EAND32)=4THENA$="て゛んち":I=32:GOTO1490
510　IFC*I=24AND(EAND4)=0THENA$="かき゛":I=4:GOTO1490
520　IFC+I=1THENA$="ふし゛さんのえて゛す。":RETURN
530　IFC=4ANDI+J=4THENA$="これはかくしきんこた゛！":GOTO1480
540　IFC*I=14THENA$="やけにかるいたんすて゛す。":RETURN
550　IFC*I=28THENA$="あやしい...。":RETURN
560　IFC=9THENA$="なにかたいせつなものか゛はいっていそうて゛す。":RETURN
570　IFC=3ANDI=1ORC*I=7THENA$="「このスタント゛をつけるな」とかいてあります。":RETURN
580　IF(C=0ORC=2)ANDI+(DAND4)=4THENA$="ハ゜スワート゛にゅうりょくしきて゛す。":RETURN
590　IFC=2ANDI+J=4ORC=4ANDI+(EAND64)=3ORC*I+(EAND128)=15THENH=1
600　IFC*J=18ANDI*(DAND1)=2ORH=1THENA$="なにかしかけか゛ありそうて゛す。":RETURN
610　IFC=4ANDI=3THENA$="こわれているようて゛す。":RETURN
620　IF(C=0ANDI=2ORC*I=16ORC=6ANDI=2)ANDD+2AND2THENH=1
630　IFC*I=5ORC*I=21ORC*(I+(EAND16))=19ORH=1THEN900
640　IFC<5ANDI*(DAND1)=2ORC=6ANDI*J=8ORC*I=24THEN660
650　IFCAND1ORD+4AND4ORI<4THENA$="かわったところはありません。":RETURN
660　A$="なにもありません。":RETURN
670　GOSUB760:IFI=0THENRETURN
680　IFC+I+J=4THENA$="えのかけ゛にきんこか゛あった！":GOTO1480
690　IFC*I+J=17THENA$="たんすのかけ゛にた゛んろか゛あった！":GOTO1480
700　IFC+I=1ORC*I=14THENA$="もううこ゛いたあとて゛す。":RETURN
710　A$="ひ゛くともしません。":RETURN
720　GOSUB760:IFI=0THENRETURN
730　IFC*J=18ANDI*(DAND1)=2THENA$="たんすにあなか゛あいた！":GOTO1480
740　IFC=2ANDI*J=3THENA$="かくしきんこか゛て゛てきた！":GOTO1480
750　GOTO710
760　FORI=1TOJ:LOCATE10,6+I:PRINTI"　"B$(C,I):NEXT
770　H=J:GOSUB1560:RETURN
780　IFC=3THENA$="あけるものはありません。":RETURN
790　I=0:IFC<5THENI=1:LOCATE11,7:PRINT"１　とた゛な
800　IFC=9THENI=1:LOCATE11,7:PRINT"１　た゛いきんこ":GOTO840
810　IFC>5THENI=1:LOCATE11,7:PRINT"１　たんす
820　IFC=1ORC>4THENI=I+1:LOCATE10,6+I:PRINTI"　まと゛
830　IFC<5ANDJ=4THENI=2:LOCATE11,8:PRINT"２　きんこ
840　H=I:GOSUB1560:IFI=0THENRETURN
850　IFC=9OR(C<5ANDI*J=8)THEN950
860　IFC<5ANDI=1THEN920
870　IFC*I+(DAND4)=12THEND=D+4:GOTO910
880　IFI=1ANDDAND1ORC*I=12THEN940
890　IFC+(DAND2)=8THEND=D+1:GOTO910
900　A$="かき゛か゛かかっています。":RETURN
910　A$="Ｏｋ！":RETURN
920　IFC+(DAND2)=0ORC+(DAND2)=5THEN900
930　IFD+1AND1THEND=D+1:GOTO910
940　A$="もうあいています。":RETURN
950　IFDAND4THEN940
960　IFC+(DAND2)=4THEN900
970　IFC=4THEN1060
980　B$="":LOCATE0,15:PRINT"ハ゜スワート゛をいれてくた゛さい。(";:H=4+(C=2)
990　PRINTH"　)";:FORI=1TOH
1000　A$=INKEY$:IFA$=""THEN1000
1010　B$=B$+A$:LOCATE22,15:PRINTB$;:NEXT
1020　ON-(C=2)-(C=9)*2GOTO1050,1070
1030　IFB$=CHR$(51)+CHR$(55)+CHR$(55)+CHR$(54)THEN1060
1040　A$="ちか゛います。":RETURN
1050　IFB$<>CHR$(115)+CHR$(112)+CHR$(121)THEN1040
1060　D=D+4:GOTO910
1070　IFB$=CHR$(145)+CHR$(151)+CHR$(150)+CHR$(252)THEN1630
1080　GOTO1040
1090　I=0:IFC=3ORC=4ORC=7THENI=1:LOCATE11,7:PRINT"1　スタント゛
1100　IFC=3ORC=5THENI=I+1:LOCATE10,6+I:PRINTI"　テレヒ゛
1110　IFI=0THENA$="つけるものはありません。":I=1:RETURN
1120　H=I:GOSUB1560:IFI=0THENRETURN
1130　IFC=7ORC*I=3THEN1600
1140　IFC+(EAND64)=4THENA$="マッチ":I=64:GOTO1490
1150　IFC=4THENA$="つきません。":RETURN
1160　IFDAND2THENA$="もうついています。":RETURN
1170　A$="「&・いろは・・・":IFC=5THENA$="「73　70　79・36　38　14　13
1180　A$=A$+"」とて゛ました。":D=D+2:RETURN
1190　H=1:IFE=0THENA$="なにももっていません。":RETURN
1200　FORI=1TO5:A(I)=0:NEXT
1210　A$="マッチ":I=64:GOSUB1450
1220　A$="ハンマー":I=16:GOSUB1450
1230　A$="かやく":I=128:GOSUB1450
1240　A$="ライト":I=8:GOSUB1450
1250　IFEAND7THENLOCATE10,6+H:PRINTH"　かき゛":H=H+1
1260　H=H-1:GOSUB1560:I=I+A(I)
1270　IFI=0THENRETURN
1280　ONIGOTO1350,1340,1360,1410
1290　IFC=2ORC=3ORC=9ORDAND2ORC*J=12THENA$="かき゛はかかっていません。":RETURN
1300　IFCAND1THEN1330
1310　I=-(C=4)-(C=6)*2-(C=0)*4
1320　IFEANDITHEND=D+2:GOTO910
1330　A$="かき゛か゛あいません。":RETURN
1340　IFC+(EAND128)=5THENA$="かやく":I=128:GOTO1490
1350　A$="いまはつかってもいみか゛ありません。":RETURN
1360　IFE+64AND64THENA$="ひをつけられません。":RETURN
1370　IFC<7ORJ=3THEN1600
1380　GOSUB1620:LOCATE0,15:PRINT"た゛んろをはかいした！　かへ゛に大あなか゛あいています。";
1390　FORI=1TO800:NEXT:A$="はいります。まっくらて゛なにもみえません。
1400　FORI=1TO4:LOCATE16,I:PRINTSPC(5):NEXT:C=8:RETURN
1410　IFE+32AND32THENA$="て゛んちか゛ないとつかえません。":RETURN
1420　IFC-8THEN1350
1430　C=9:J=1:B$(9,1)="た゛いきんこ":LOCATE16,1:PRINT"た゛いきんこ
1440　A$="あかるくなりました。":RETURN
1450　A(H)=A(H)+1:IFE+IANDITHENRETURN
1460　LOCATE10,6+H:PRINTH"　"A$
1470　A(H)=A(H)-1:H=H+1:A(H)=A(H-1):RETURN
1480　J=4:LOCATE16,4:PRINTB$(C,4):RETURN
1490　E=E+I:IFI<5THENI=(EAND1)+(EAND2)/2+(EAND4)/4
1500　IFI=2ORI=3THENLOCATE28,7:PRINTI
1510　I=7-(I=16)-(I=64)*2-(I=32)*3-(I=128)*4-(I=8)*5
1520　LOCATE25,I:PRINTA$:A$=A$+"か゛あった！
1530　IFI=9THENA$="マッチか゛て゛てきた！
1540　IFC=5THENA$="つくえか゛こわれてかやくか゛て゛てきた！
1550　RETURN
1560　A$=INKEY$:IFA$=""THEN1560
1570　IF"　"+A$>STR$(H)ORA$<"0"THEN1560
1580　I=VAL(A$):IFITHENPSET(8-(H<7)*80,I*12+72),2
1590　RETURN
1600　GOSUB1620:LOCATE0,15:PRINT"た゛いは゛くはつて゛す。−ＧＡＭＥ　ＯＶＥＲ−";
1610　GOTO1610
1620　SOUND6,30:SOUND7,7:SOUND8,16:SOUND12,90:SOUND13,0:RETURN
1630　LOCATE0,15:PRINT"Ｏｋ！"TAB(28):FORI=1TO500:NEXT
1640　LOCATE0,15:PRINT"　　　";
1650　CLEAR332:RESTORE1780:FORI=1TO166:READA$:B$=B$+CHR$(VAL("&H"+A$))
1660　A$=MID$(B$,-(I<32)-(I>31)*(I-30),-(I<32)*I-(I>31)*31)
1670　LOCATE-(I<32)*(31-I),15:PRINTA$;:NEXT
1680　LOCATE11,15:PRINT"ＧＡＭＥ　ＯＶＥＲ";:GOTO1680
1690　DATAしらへ゛る,うこ゛かす,おす,あける,つける,つかう,へやをて゛る
1700　DATAえ,とた゛な,つくえ,きんこ
1710　DATAえ,とた゛な,まと゛,
1720　DATAえ,とた゛な,つくえ,きんこ
1730　DATAスタント゛,テレヒ゛,つくえ,
1740　DATAえ,とた゛な,スタント゛,きんこ
1750　DATAまと゛,テレヒ゛,つくえ,
1760　DATAえ,たんす,まと゛,あな
1770　DATAスタント゛,たんす,まと゛,た゛んろ
1780　DATA95,F2,E3,DE,E4,93,A1,F6,98,F4,8F,E3,98,FA,E0,A1,9A,FA
1790　DATAE3,DE,FC,96,DE,98,E6,96,DE,F5,93,9E,92,E6,E5,F9,9A,E4
1800　DATAEA,EF,E1,96,DE,92,E5,92,A1,97,F0,F3,A4,EB,F7,E9,BD,CA
1810　DATADF,B2,96,F7,E0,DE,92,96,FD,EC,DE,ED,9C,8E,93,9C,FD,E0
1820　DATADE,21,A5,A5,A5,A5,A5,A5,E4,92,92,E0,92,96,DE,A4,97,F0
1830　DATA96,DE,EB,F0,E2,9C,8E,F9,92,E9,9A,E4,86,9C,8F,E3,92,F9
1840　DATA92,9C,DE,8E,93,A4,92,96,9C,E3,EA,95,99,E5,92,E9,E0,DE
1850　DATAA1,9C,FD,E3,DE,F3,F7,93,A1,20,20,20,20,20,20,20,20,20
1860　DATA20,20,20,20,20,20,20,20,20,20,20,20,20,20,20,20,20,20
1870　DATA20,20,20,20

トップ > 雑多なもの > PC-6001自作ゲーム思い出語り > THE SPY リスト